le mot de passe n'expire jamais.

[birdie]

Je souhaiterais "cocher" le mot de passe n'expire jamais pour un groupe d'utilisateurs et non passer les comptes un à un...pour cocher la fameuse case.
Je précise que je ne suis pas informaticien... quoi ? vous l'aviez devinné ?

Vous devez avoir une solution je pense.

Merci à vous !

[Waryx]

TU es donc sous 2000 Server ?
Car sous 2003 il est possible de sélectionner plusieurs utilisateurs d'un coup pour en modifier les propriétés.

Je pense qu'il faudra passer par un script sinon

[bigstyle]

Un exemple : http://www.jsifaq.com/SF/Tips/Tip.aspx?id=9625

[birdie]

et dans ce script que faut il que j'adapte pour que ça fonctionne pour un groupe d'étudiants ?

c'est un peu du chinois pour moi...

merci

[Waryx]

Pourtant si tu ne veux pas le faire à la main et que tu es sous windows 2000 server il va falloir te mettre au script pour automatiser ta tache

[birdie]

merci a vous deux pour les infos !
je vais m'y mettre dès lundimais je voudrais savoir
a quoi m'attendre...

ce fichier PwdNX.bat ou dois je l'enregistrer sur le serveur ?
y'a ti-l un lieu précis ?

ensuite je suppose qu'il faudra le lancer et que va t -il se passer ...


Vous comprendrez que je suis trés prudent.
150 etudiants et eleves du lycée travaillent sur le serveur
et je ne souhaite pas les priver de ça...
Je suis un peu frileux quoi ...

[Waryx]

le problème de ce script au premier coup d'oeil c'est qu'il le fait pour un user et non pour tous...

Il faudrait regader du script center si en VBS il n'y aurait pas quelque chose...

[bigstyle]

Tu peux aussi regarder du coté de adfind | admod

[birdie]

et il n'existe pas de petits logiciles qui permettent
de passer en revue les differents utilisateurs ?
et de cocher dans un tableau que le mot de passe n'expire jamais?
du style:


mot de passe expire

oui non
alain | X
bruno | X
catherine | X
etc...

ça n'existe pas ça ?
ça me perttrait d'aller plus vite...
et d'éviter de faire propriéte, compte a chaque fois.

[Waryx]

et d'éviter de faire propriéte, compte a chaque fois.

Pas à ma connaissance, surtout que ce problème ne se pose plus depuis 2003 et la possibilité de modifier plusieurs comptes d'un seul coup...

[bigstyle]

et il n'existe pas de petits logiciles qui permettent
de passer en revue les differents utilisateurs ?
et de cocher dans un tableau que le mot de passe n'expire jamais?
du style:


mot de passe expire

oui non
alain | X
bruno | X
catherine | X
etc...

ça n'existe pas ça ?
ça me perttrait d'aller plus vite...
et d'éviter de faire propriéte, compte a chaque fois.

avec adfind et admod tu peux repérer les utilisateurs qui ont cet attribut défini (via adfind) et modifie celui-ci (via admod).

[marcww]

Salut

As-tu vraiment besoin que le mot de passe expire pour certains comptes ?

Marc

[Goran]

Salut,

Solution en VBS :

1. Liste tous les comptes utilisateurs et l'état de l'option à partir d'une OU donnée :

Code: Tout sélectionner

On Error Resume Next

Const USERS_LIST = "UsersList.csv"
Const ForWriting = 2
Const ADS_UF_DONT_EXPIRE_PASSWD = &h10000

Set objRootDSE = GetObject("LDAP://rootDSE" )
Set objFSO = CreateObject("Scripting.FileSystemObject")

Set fsoListUsers = objFSO.OpenTextFile(USERS_LIST, ForWriting, True)

ListOU("OU=SousOU,OU=OURacine")

fsoListUsers.Close
Wscript.Echo "Terminé"


Sub ListOU(strOU)
   Set objOU = GetObject("LDAP://" & strOU & "," & objRootDSE.Get("defaultNamingContext"))
   objOU.Filter = Array("organizationalUnit","user")
   For Each objItem In objOU
      If objItem.Class = "user" Then
         If IsExpirePassword(objItem.Name,strOU) Then
            fsoListUsers.Writeline objItem.Name & VbTab & strOU & VbTab & ""
         Else
            fsoListUsers.Writeline objItem.Name & VbTab & strOU & VbTab & "x"
         End If
      End If
      If objItem.Class = "organizationalUnit" Then
         ListOU(objItem.Name & "," & strOU)
      End If
   Next
End Sub

Function IsExpirePassword(strUser,strOU)
   Set objUser = GetObject ("LDAP://" & strUser & "," & strOU & "," & objRootDSE.Get("defaultNamingContext"))
   intUAC = objUser.Get("userAccountControl")

   If ADS_UF_DONT_EXPIRE_PASSWD AND intUAC Then
      IsExpirePassword = FALSE
   Else
      IsExpirePassword = TRUE
   End If
End Function

Il faut modifier la ligne "ListOU("OU=SousOU,OU=OURacine")" pour préciser l'OU à lister (en partant de l'OU racine bien sûr).
Si on veut le faire pour plusieurs OU d'arborescences différentes, il suffit de rajouter les lignes "ListOU" correspondantes.
A noter que le script liste le contenu des sous OU.
Le fichier créé utilise la tabulation comme caratère de séparation, ce qui permet de l'ouvrir sous Excel. Le nom et le chemin peuvent être modifiés via la constante "USERS_LIST".
Si l'option "Le mot de passe n'expire jamais" est active pour un compte, elle est signalée par un "x" en troisième colonne.

2. Active/Désactive l'option à partir du fichier :

Code: Tout sélectionner

On Error Resume Next

Const USERS_LIST = "UsersList.txt"
Const ForReading = 1
Const ADS_UF_DONT_EXPIRE_PASSWD = &h10000

Set objRootDSE = GetObject("LDAP://rootDSE" )
Set objFSO = CreateObject("Scripting.FileSystemObject")

Set fsoListUsers = objFSO.OpenTextFile(USERS_LIST, ForReading)

Main()

fsoListUsers.Close
Wscript.Echo "Terminé"


Sub Main()
   Do Until fsoListUsers.AtEndOfStream
      strFileInfo = fsoListUsers.ReadLine
      arrFileInfo = Split(strFileInfo,"   ")
      strUser = arrFileInfo(0)
      strOU = arrFileInfo(1)
      strPasswordOption = arrFileInfo(2)
      If Ucase(strPasswordOption) = "X" Then
         SetPasswordNeverExpire strUser,strOU,TRUE
      Else
         SetPasswordNeverExpire strUser,strOU,FALSE
      End If
   Loop
End Sub

Sub SetPasswordNeverExpire(strUser,strOU,Enable)
   Set objUser = GetObject ("LDAP://" & strUser & "," & strOU & "," & objRootDSE.Get("defaultNamingContext"))
   intUAC = objUser.Get("userAccountControl")

   If Enable Then
      If ADS_UF_DONT_EXPIRE_PASSWD AND intUAC Then
      Else
         objUser.Put "userAccountControl", intUAC XOR ADS_UF_DONT_EXPIRE_PASSWD
         objUser.SetInfo
      End If
   Else
      If ADS_UF_DONT_EXPIRE_PASSWD AND intUAC Then
         objUser.Put "userAccountControl", intUAC XOR ADS_UF_DONT_EXPIRE_PASSWD
         objUser.SetInfo
      End If
   End If
End Sub

Il suffit de rajouter (ou de supprimer) un "x" (peu importe la casse) en troisième colonne pour modifier l'option pour le compte (activer/désactiver).
Le nom et le chemin du fichier source peuvent être modifiés via la constante "USERS_LIST".